sway-hidpi/PKGBUILD

# Maintainer: Antonin Décimo <antonin dot decimo at gmail dot com>
# Contributor: Drew DeVault <sir@cmpwn.com>
pkgname=sway-hidpi
pkgver=1.6
pkgrel=1
license=("MIT")
pkgdesc="Tiling Wayland compositor and replacement for the i3 window manager, with XWayland HiDPI (git version)"
makedepends=(
	"git"
	"meson"
	"ninja"
	"scdoc"
	"wayland-protocols"
)
depends=(
	"cairo"
	"gdk-pixbuf2"
	"json-c"
	"pango"
	"polkit"
	"pcre"
	"ttf-font"
	"wlroots-hidpi"
	"xorg-xwayland-hidpi-git"
        "xsettingsd"
)
optdepends=(
	"alacritty: Terminal emulator used by the default config"
	"dmenu: Application launcher"
	"grim: Screenshot utility"
	"i3status: Status line"
	"mako: Lightweight notification daemon"
	"slurp: Select a region"
	"swayidle: Idle management daemon"
	"swaylock: Screen locker"
	"wallutils: Timed wallpapers"
	"waybar: Highly customizable bar"
)
backup=(etc/sway/config)
arch=("i686" "x86_64")
url="https://swaywm.org"
source=("${pkgname}::git+https://github.com/swaywm/sway.git#tag=${pkgver}"
        "50-systemd-user.conf"
        "xwayland_hidpi.diff::https://github.com/swaywm/sway/compare/${pkgver}...MisterDA:xwayland_hidpi.diff")
sha512sums=('SKIP'
            '57590bc0d14c87289a4a9cd67991c6a841e54244d2a6186b5da5a08e633de2e8631959fa8c77ede211b0a5f315d920f2c1350951a53d6f2e9e81859056cb3c9e'
            'c1786e978a63d0b6ca41ce78c508ab2541272bb9a8484c2f0c04ee463e3fe8cc318c9421e9381c391e40ccc7e45f116f6c73dc264aaaaf2809cd16d7a5db424e')
provides=("sway")
conflicts=("sway")
options=(debug)

prepare() {
	cd "$pkgname"
	patch --forward --strip=1 --input="${srcdir}/xwayland_hidpi.diff"
}

build() {
	cd "$pkgname"
	meson \
		-Dwerror=false \
		--prefix /usr \
		"$srcdir/build"
	ninja -C "$srcdir/build"
}

package() {
	install -Dm644 50-systemd-user.conf -t "$pkgdir/etc/sway/config.d/"

	cd "$pkgname"
	DESTDIR="$pkgdir" ninja -C "$srcdir/build" install

	install -Dm644 "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"

	for util in autoname-workspaces.py inactive-windows-transparency.py grimshot; do
		install -Dm755 "contrib/$util" -t "$pkgdir/usr/share/$pkgname/scripts"
	done
}