Initial import

.SRCINFO

@@ -0,0 +1,26 @@
+pkgbase = wlroots-git
+	pkgdesc = Modular Wayland compositor library
+	pkgver = r1744.60b2d96
+	pkgrel = 1
+	url = https://github.com/swaywm/wlroots
+	arch = x86_64
+	license = custom:MIT
+	makedepends = meson
+	makedepends = ninja
+	depends = libcap
+	depends = systemd
+	depends = wayland
+	depends = opengl-driver
+	depends = libxcb
+	depends = xcb-util-image
+	depends = xcb-util-wm
+	depends = pixman
+	depends = libinput
+	depends = libxkbcommon
+	provides = wlroots
+	conflicts = wlroots
+	source = wlroots-git::git+https://github.com/swaywm/wlroots
+	sha512sums = SKIP
+
+pkgname = wlroots-git
+

.gitignore

@@ -0,0 +1,5 @@
+/wlroots-git/
+/pkg/
+/src/
+*.pkg.tar
+*.pkg.tar.*

PKGBUILD

@@ -0,0 +1,44 @@
+# Maintainer: Adrian Perez de Castro <aperez@igalia.com>
+pkgname='wlroots-git'
+pkgver=r1744.60b2d96
+pkgrel=1
+license=('custom:MIT')
+pkgdesc='Modular Wayland compositor library'
+url='https://github.com/swaywm/wlroots'
+arch=('x86_64')
+provides=('wlroots')
+conflicts=('wlroots')
+depends=('libcap' 'systemd' 'wayland' 'opengl-driver' 'libxcb'
+         'xcb-util-image' 'xcb-util-wm' 'pixman' 'libinput'
+		 'libxkbcommon')
+makedepends=('meson' 'ninja')
+source=("${pkgname}::git+${url}")
+sha512sums=('SKIP')
+
+
+pkgver () {
+	cd "${pkgname}"
+	(
+		set -o pipefail
+		git describe --long 2>/dev/null | sed 's/\([^-]*-g\)/r\1/;s/-/./g' | sed 's/^version\.//' ||
+		printf "r%s.%s" "$(git rev-list --count HEAD)" "$(git rev-parse --short HEAD)"
+	)
+}
+
+build () {
+	cd "${pkgname}"
+	rm -rf build
+	meson build \
+		--prefix /usr \
+		-Denable_xwayland=true \
+		-Denable_libcap=true \
+		-Denable_systemd=true \
+		-Denable_elogind=false
+	ninja -C build
+}
+
+package () {
+	cd "${pkgname}"
+	DESTDIR="${pkgdir}" ninja -C build install
+	install -Dm644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
+}