mirror of
git://projects.qi-hardware.com/cae-tools.git
synced 2024-12-23 09:55:32 +02:00
ddcf5191db
- README, lang.y: changed depth parameter of "z" command to position (sign changes) - lang.l: defer FILENAME after "gerber" and "gnuplot", so that we don't mis-read the number - lang.l, lang.y: return the reference point after "align" as new token REF, not as NUMEBER, so that we can catch syntax errors that would cause scanner and parser to become unsynchronized - lang.l: accept negative numbers - lang.l: added support for comments beginning with #
107 lines
2.2 KiB
Plaintext
107 lines
2.2 KiB
Plaintext
%{
|
|
/*
|
|
* lang.l - Toolpath adaptation language
|
|
*
|
|
* Written 2010 by Werner Almesberger
|
|
* Copyright 2010 by Werner Almesberger
|
|
*
|
|
* This program is free software; you can redistribute it and/or modify
|
|
* it under the terms of the GNU General Public License as published by
|
|
* the Free Software Foundation; either version 2 of the License, or
|
|
* (at your option) any later version.
|
|
*/
|
|
|
|
|
|
#include <stdlib.h>
|
|
#include <stdio.h>
|
|
|
|
#include "y.tab.h"
|
|
|
|
|
|
void yyerror(const char *s);
|
|
|
|
static int lineno = 1;
|
|
static int metric = 1;
|
|
static int file_name_follows = 0;
|
|
|
|
|
|
#define MIL2MM(mil) ((mil)/1000*25.4)
|
|
|
|
%}
|
|
|
|
/* file name can contain any characters */
|
|
%s FILENAME
|
|
|
|
/* "align" has a one-digit argument we don't want to subject to unit
|
|
conversion */
|
|
%s DIGIT
|
|
|
|
NUM -?[0-9]+\.?[0-9]*
|
|
|
|
%%
|
|
|
|
|
|
<INITIAL>align { BEGIN(DIGIT);
|
|
return TOK_ALIGN; }
|
|
<INITIAL>array return TOK_ARRAY;
|
|
<INITIAL>clear return TOK_CLEAR;
|
|
<INITIAL>reset return TOK_RESET;
|
|
<INITIAL>tool return TOK_TOOL;
|
|
<INITIAL>translate return TOK_TRANSLATE;
|
|
<INITIAL>z return TOK_Z;
|
|
|
|
<INITIAL>gerber { file_name_follows = 1;
|
|
return TOK_GERBER; }
|
|
<INITIAL>gnuplot { file_name_follows = 1;
|
|
return TOK_GNUPLOT; }
|
|
<INITIAL>write { BEGIN(FILENAME);
|
|
return TOK_WRITE; }
|
|
|
|
<INITIAL>dog return TOK_DOG;
|
|
|
|
<INITIAL>mm metric = 1;
|
|
<INITIAL>mil metric = 0;
|
|
|
|
<DIGIT>[1-9] { BEGIN(INITIAL);
|
|
yylval.num = strtod(yytext, NULL);
|
|
return REF; }
|
|
|
|
{NUM}mm { yylval.num = strtod(yytext, NULL);
|
|
if (file_name_follows)
|
|
BEGIN(FILENAME);
|
|
return NUMBER; }
|
|
{NUM}mil { yylval.num = MIL2MM(strtod(yytext, NULL));
|
|
if (file_name_follows)
|
|
BEGIN(FILENAME);
|
|
return NUMBER; }
|
|
{NUM} { yylval.num = strtod(yytext, NULL);
|
|
if (!metric)
|
|
yylval.num = MIL2MM(yylval.num);
|
|
if (file_name_follows)
|
|
BEGIN(FILENAME);
|
|
return NUMBER; }
|
|
|
|
<FILENAME>[^ \t\n]+([^\t\n]*[^ \t\n]+)? {
|
|
BEGIN(INITIAL);
|
|
file_name_follows = 0;
|
|
yylval.str = yytext;
|
|
return STRING; }
|
|
|
|
[ \t] ;
|
|
\n lineno++;
|
|
|
|
^#\ [0-9]+\ \"[^"]*\"(\ [0-9]+)*\n {
|
|
lineno = strtol(yytext+2, NULL, 0); }
|
|
|
|
<INITIAL>#.*\n lineno++;
|
|
|
|
. return *yytext;
|
|
|
|
%%
|
|
|
|
void yyerror(const char *s)
|
|
{
|
|
fprintf(stderr, "%d: %s near \"%s\"\n", lineno, s, yytext);
|
|
exit(1);
|
|
}
|