mirror of
git://projects.qi-hardware.com/openwrt-xburst.git
synced 2024-12-27 07:40:50 +02:00
5d2766e7eb
Hi, the attached patch makes ipcalc.sh accept IP/Netmask combinations in CIDR notation. Before you could only do: # sh ipcalc.sh 192.168.0.0 255.255.255.0 1 10 IP=192.168.0.0 NETMASK=255.255.255.0 BROADCAST=192.168.0.255 NETWORK=192.168.0.0 PREFIX=24 START=192.168.0.1 END=192.168.0.11 with this patch you can also execute it with: sh ipcalc.sh 192.168.0.0/24 1 10 IP=192.168.0.0 NETMASK=255.255.255.0 BROADCAST=192.168.0.255 NETWORK=192.168.0.0 PREFIX=24 START=192.168.0.1 END=192.168.0.11 The patch is based on #1260 [1], i just changed one line to calculate the START end END ips right. I wonder why that never got included. If there is no reason not to do i would like to ask you to commit that patch, because its a functionality i (and probably others) miss quite often. Btw, i also fixed 4 useless tabs, that might look a bit strange in the patch. Regards, Manuel git-svn-id: svn://svn.openwrt.org/openwrt/trunk@26930 3c298f89-4303-0410-b956-a3cf2f4a3e73
63 lines
1.3 KiB
Bash
Executable File
63 lines
1.3 KiB
Bash
Executable File
#!/bin/sh
|
|
|
|
awk -f - $* <<EOF
|
|
function bitcount(c) {
|
|
c=and(rshift(c, 1),0x55555555)+and(c,0x55555555)
|
|
c=and(rshift(c, 2),0x33333333)+and(c,0x33333333)
|
|
c=and(rshift(c, 4),0x0f0f0f0f)+and(c,0x0f0f0f0f)
|
|
c=and(rshift(c, 8),0x00ff00ff)+and(c,0x00ff00ff)
|
|
c=and(rshift(c,16),0x0000ffff)+and(c,0x0000ffff)
|
|
return c
|
|
}
|
|
|
|
function ip2int(ip) {
|
|
for (ret=0,n=split(ip,a,"\."),x=1;x<=n;x++) ret=or(lshift(ret,8),a[x])
|
|
return ret
|
|
}
|
|
|
|
function int2ip(ip,ret,x) {
|
|
ret=and(ip,255)
|
|
ip=rshift(ip,8)
|
|
for(;x<3;ret=and(ip,255)"."ret,ip=rshift(ip,8),x++);
|
|
return ret
|
|
}
|
|
|
|
BEGIN {
|
|
slpos=index(ARGV[1],"/")
|
|
if (slpos == 0) {
|
|
ipaddr=ip2int(ARGV[1])
|
|
netmask=ip2int(ARGV[2])
|
|
} else {
|
|
ipaddr=ip2int(substr(ARGV[1],0,slpos-1))
|
|
netmask=compl(2**(32-int(substr(ARGV[1],slpos+1)))-1)
|
|
ARGV[4]=ARGV[3]
|
|
ARGV[3]=ARGV[2]
|
|
}
|
|
|
|
network=and(ipaddr,netmask)
|
|
broadcast=or(network,compl(netmask))
|
|
|
|
start=or(network,and(ip2int(ARGV[3]),compl(netmask)))
|
|
limit=network+1
|
|
if (start<limit) start=limit
|
|
|
|
end=start+ARGV[4]
|
|
limit=or(network,compl(netmask))-1
|
|
if (end>limit) end=limit
|
|
|
|
print "IP="int2ip(ipaddr)
|
|
print "NETMASK="int2ip(netmask)
|
|
print "BROADCAST="int2ip(broadcast)
|
|
print "NETWORK="int2ip(network)
|
|
print "PREFIX="32-bitcount(compl(netmask))
|
|
|
|
# range calculations:
|
|
# ipcalc <ip> <netmask> <start> <num>
|
|
|
|
if (ARGC > 3) {
|
|
print "START="int2ip(start)
|
|
print "END="int2ip(end)
|
|
}
|
|
}
|
|
EOF
|