eda-tools/b2/lang.l

%{
/*
 * lang.l - BOOM syntax
 *
 *  Copyright 2012 by Werner Almesberger
 *
 * This program is free software; you can redistribute it and/or modify
 * it under the terms of the GNU General Public License as published by
 * the Free Software Foundation; either version 2 of the License, or
 * (at your option) any later version.
 */

#include <stdarg.h>
#include <stdlib.h>
#include <unistd.h>
#include <fcntl.h>

#include "util.h"
#include "param.h"
#include "chr.h"
#include "y.tab.h"
#include "lang.h"


extern int yyparse(void);

static int start_token;
static int expose_nl;
static const char *file_name;
static int lineno;


static void open_stdin(const char *name)
{
	int fd;

	fd = open(name, O_RDONLY);
	if (fd < 0) {
		perror(name);
		exit(1);
	}
	if (dup2(fd, 0) < 0) {
		perror("dup2");
		exit(1);
	}
}


static void do_parse(const char *name, int start, int nl)
{
	open_stdin(name);
	
	start_token = start;
	expose_nl = nl;
	file_name = unique(name);
	lineno = 1;
	yyparse();
}


void parse_hierarchy(const char *name)
{
	do_parse(name, START_HIERARCHY, 0);
}


void parse_characteristics(const char *name)
{
	do_parse(name, START_CHAR, 1);
}


void parse_inventory(const char *name)
{
	do_parse(name, START_INVENTORY, 1);
}


void parse_currencies(const char *name)
{
	do_parse(name, START_EXCHANGE, 1);
}


void parse_providers(const char *name)
{
	do_parse(name, START_PROVIDERS, 1);
}

%}


/*
 * We use ID for a bit of a hack: let %... be recognized as '%' WORD but treat
 * ...% still as a single WORD.
 */

ID	[-_A-Za-z0-9()+./]

%%

%{
	if (start_token) {
		int tmp = start_token;

		start_token = 0;
		return tmp;
	}
%}

{ID}({ID}|"%")*			{ yylval.s = unique(yytext);
				  return WORD; }

"<="				return TOK_LE;
">="				return TOK_GE;

"//"[^\n]*			;
"/*"([^*]|("*"+([^*/])))*"*"+"/" { const char *s = yytext;
				  while (*s)
					lineno += *s++ == '\n'; }

[ \t]				;
\n				{ lineno++;
				  if (expose_nl)
					return TOK_NL; }
^#[^n]*\n			lineno++;

.				return *yytext;

%%


void yywarnf(const char *fmt, ...)
{
	va_list ap;

	va_start(ap, fmt);
	fprintf(stderr, "%s:%d: warning: ", file_name, lineno);
	vfprintf(stderr, fmt, ap) ;
	fprintf(stderr, "\n");
	va_end(ap);
}


void yyerrorf(const char *fmt, ...)
{
	va_list ap;

	va_start(ap, fmt);
	fprintf(stderr, "%s:%d: ", file_name, lineno);
	vfprintf(stderr, fmt, ap) ;
	fprintf(stderr, "\n");
	va_end(ap);
	exit(1);
}


void yyerror(const char *s)
{
	fprintf(stderr, "%s:%d: %s\n", file_name, lineno, s);
	exit(1);
}